Clarity Language Reference

This file contains the reference for the Clarity language.

Clarity Type System

The Clarity language uses a strong static type system. Function arguments and database schemas require specified types, and use of types is checked during contract launch. The type system does not have a universal super type. The type system contains the following types:

  • (tuple (key-name-0 key-type-0) (key-name-1 key-type-1) ...) - a typed tuple with named fields.
  • (list max-len entry-type) - a list of maximum length max-len, with entries of type entry-type
  • (response ok-type err-type) - object used by public functions to commit their changes or abort. May be returned or used by other functions as well, however, only public functions have the commit/abort behavior.
  • (optional some-type) - an option type for objects that can either be (some value) or none
  • (buff max-len) := byte buffer or maximum length max-len.
  • principal := object representing a principal (whether a contract principal or standard principal).
  • bool := boolean value (true or false)
  • int := signed 128-bit integer
  • uint := unsigned 128-bit integer

Public Functions

Functions specified via define-public statements are public functions and these are the only types of functions which may be called directly through signed blockchain transactions. In addition to being callable directly from a transaction (see the Stacks wire formats for more details on Stacks transactions), public function may be called by other smart contracts.

Public functions must return a (response ...) type. This is used by Clarity to determine whether or not to materialize any changes from the execution of the function. If a function returns an (err ...) type, and mutations on the blockchain state from executing the function (and any function that it called during execution) will be aborted.

In addition to function defined via define-public, contracts may expose read-only functions. These functions, defined via define-read-only, are callable by other smart contracts, and may be queryable via public blockchain explorers. These functions may not mutate any blockchain state. Unlike normal public functions, read-only functions may return any type.

Contract Calls

A smart contract may call functions from other smart contracts using a (contract-call?) function.

This function returns a response type result– the return value of the called smart contract function.

We distinguish 2 different types of contract-call?:

  • Static dispatch: the callee is a known, invariant contract available on-chain when the caller contract is deployed. In this case, the callee’s principal is provided as the first argument, followed by the name of the method and its arguments:
(contract-call?
    .registrar
    register-name
    name-to-register)
  • Dynamic dispatch: the callee is passed as an argument, and typed as a trait reference ().
(define-public (swap (token-a <can-transfer-tokens>)
                     (amount-a uint)
                     (owner-a principal)
                     (token-b <can-transfer-tokens>)
                     (amount-b uint)
                     (owner-b principal)))
     (begin
         (unwrap! (contract-call? token-a transfer-from? owner-a owner-b amount-a))
         (unwrap! (contract-call? token-b transfer-from? owner-b owner-a amount-b))))

Traits can either be locally defined:

(define-trait can-transfer-tokens (
    (transfer-from? (principal principal uint) (response uint)))

Or imported from an existing contract:

(use-trait can-transfer-tokens
    .contract-defining-trait.can-transfer-tokens)

Looking at trait conformance, callee contracts have two different paths. They can either be “compatible” with a trait by defining methods matching some of the methods defined in a trait, or explicitely declare conformance using the impl-trait statement:

(impl-trait .contract-defining-trait.can-transfer-tokens)

Explicit conformance should be prefered when adequate. It acts as a safeguard by helping the static analysis system to detect deviations in method signatures before contract deployment.

The following limitations are imposed on contract calls:

  1. On static dispatches, callee smart contracts must exist at the time of creation.
  2. No cycles may exist in the call graph of a smart contract. This prevents recursion (and re-entrancy bugs). Such structures can be detected with static analysis of the call graph, and will be rejected by the network.
  3. contract-call? are for inter-contract calls only. Attempts to execute when the caller is also the callee will abort the transaction.

Keyword reference

block-height

uint

Returns the current block height of the Stacks blockchain as an int

Example

(> block-height 1000) ;; returns true if the current block-height has passed 1000 blocks.

contract-caller

principal

Returns the caller of the current contract context. If this contract is the first one called by a signed transaction, the caller will be equal to the signing principal. If contract-call? was used to invoke a function from a new contract, contract-caller changes to the calling contract’s principal. If as-contract is used to change the tx-sender context, contract-caller also changes to the same contract principal.

Example

(print contract-caller) ;; Will print out a Stacks address of the transaction sender

false

bool

Boolean false constant.

Example

(and true false) ;; Evaluates to false
(or false true)  ;; Evaluates to true

none

(optional ?)

Represents the none option indicating no value for a given optional (analogous to a null value).

Example

(define-public (only-if-positive (a int))
  (if (> a 0)
      (some a)
      none))
(only-if-positive 4) ;; Returns (some 4)
(only-if-positive (- 3)) ;; Returns none

true

bool

Boolean true constant.

Example

(and true false) ;; Evaluates to false
(or false true)  ;; Evaluates to true

tx-sender

principal

Returns the original sender of the current transaction, or if as-contract was called to modify the sending context, it returns that contract principal.

Example

(print tx-sender) ;; Will print out a Stacks address of the transaction sender

Function reference

* (multiply)

Syntax (* i1 i2...)

INPUT: int, ... | uint, ...
OUTPUT: int | uint

Multiplies a variable number of integer inputs and returns the result. In the event of an overflow, throws a runtime error.

Example

(* 2 3) ;; Returns 6
(* 5 2) ;; Returns 10
(* 2 2 2) ;; Returns 8

+ (add)

Syntax (+ i1 i2...)

INPUT: int, ... | uint, ...
OUTPUT: int | uint

Adds a variable number of integer inputs and returns the result. In the event of an overflow, throws a runtime error.

Example

(+ 1 2 3) ;; Returns 6

- (subtract)

Syntax (- i1 i2...)

INPUT: int, ... | uint, ...
OUTPUT: int | uint

Subtracts a variable number of integer inputs and returns the result. In the event of an underflow, throws a runtime error.

Example

(- 2 1 1) ;; Returns 0
(- 0 3) ;; Returns -3

/ (divide)

Syntax (/ i1 i2...)

INPUT: int, ... | uint, ...
OUTPUT: int | uint

Integer divides a variable number of integer inputs and returns the result. In the event of division by zero, throws a runtime error.

Example

(/ 2 3) ;; Returns 0
(/ 5 2) ;; Returns 2
(/ 4 2 2) ;; Returns 1

< (less than)

Syntax (< i1 i2)

INPUT: int, int | uint, uint
OUTPUT: bool

Compares two integers, returning true if i1 is less than i2 and false otherwise.

Example

(< 1 2) ;; Returns true
(< 5 2) ;; Returns false

<= (less than or equal)

Syntax (<= i1 i2)

INPUT: int, int | uint, uint
OUTPUT: bool

Compares two integers, returning true if i1 is less than or equal to i2 and false otherwise.

Example

(<= 1 1) ;; Returns true
(<= 5 2) ;; Returns false

> (greater than)

Syntax (> i1 i2)

INPUT: int, int | uint, uint
OUTPUT: bool

Compares two integers, returning true if i1 is greater than i2 and false otherwise.

Example

(> 1 2) ;; Returns false
(> 5 2) ;; Returns true

>= (greater than or equal)

Syntax (>= i1 i2)

INPUT: int, int | uint, uint
OUTPUT: bool

Compares two integers, returning true if i1 is greater than or equal to i2 and false otherwise.

Example

(>= 1 1) ;; Returns true
(>= 5 2) ;; Returns true

and

Syntax (and b1 b2 ...)

INPUT: bool, ...
OUTPUT: bool

Returns true if all boolean inputs are true. Importantly, the supplied arguments are evaluated in-order and lazily. Lazy evaluation means that if one of the arguments returns false, the function short-circuits, and no subsequent arguments are evaluated.

Example

(and true false) ;; Returns false
(and (is-eq (+ 1 2) 1) (is-eq 4 4)) ;; Returns false
(and (is-eq (+ 1 2) 3) (is-eq 4 4)) ;; Returns true

append

Syntax (append (list 1 2 3 4) 5)

INPUT: list A, A
OUTPUT: list

The append function takes a list and another value with the same entry type, or a buffer and another buffer of length 1 and outputs a buffer or a list of the same type with max_len += 1.

Example

(append (list 1 2 3 4) 5) ;; Returns (1 2 3 4 5)

as-contract

Syntax (as-contract expr)

INPUT: A
OUTPUT: A

The as-contract function switches the current context’s tx-sender value to the contract’s principal and executes expr with that context. It returns the resulting value of expr.

Example

(as-contract tx-sender) ;; Returns S1G2081040G2081040G2081040G208105NK8PE5.docs-test

as-max-len?

Syntax (as-max-len? buffer u10)

INPUT: buff|list, uint
OUTPUT: (optional buff|list)

The as-max-len? function takes a length N (must be a literal) and a buffer or list argument, which must be typed as a list or buffer of length M and outputs that same list or buffer, but typed with max length N.

This function returns an optional type with the resulting iterable. If the input iterable is less than or equal to the supplied max-len, it returns (some <iterable>), otherwise it returns none.

Example

(as-max-len? (list 2 2 2) u3) ;; Returns (some (2 2 2))
(as-max-len? (list 1 2 3) u2) ;; Returns none

asserts!

Syntax (asserts! bool-expr thrown-value)

INPUT: bool, C
OUTPUT: bool

The asserts! function admits a boolean argument and asserts its evaluation: if bool-expr is true, asserts! returns true and proceeds in the program execution. If the supplied argument is returning a false value, asserts! returns thrown-value and exits the current control-flow.

Example

(asserts! (is-eq 1 1) (err 1)) ;; Returns true

at-block

Syntax (at-block block-hash expr)

INPUT: (buff 32), A
OUTPUT: A

The at-block function evaluates the expression expr as if it were evaluated at the end of the block indicated by the block-hash argument. The expr closure must be read-only.

Note: The block identifying hash must be a hash returned by the id-header-hash block information property. This hash uniquely identifies Stacks blocks and is unique across Stacks forks. While the hash returned by header-hash is unique within the context of a single fork, it is not unique across Stacks forks.

The function returns the result of evaluating expr.

Example

(define-data-var data int 1)
(at-block 0x0000000000000000000000000000000000000000000000000000000000000000 block-height) ;; Returns u0
(at-block (get-block-info? id-header-hash 0) (var-get data)) ;; Throws NoSuchDataVariable because `data` wasn't initialized at block height 0

begin

Syntax (begin expr1 expr2 expr3 ... expr-last)

INPUT: AnyType, ... A
OUTPUT: A

The begin function evaluates each of its input expressions, returning the return value of the last such expression.

Example

(begin (+ 1 2) 4 5) ;; Returns 5

concat

Syntax (concat buff-a buff-b)

INPUT: (buff, buff)|(list, list)
OUTPUT: buff|list

The concat function takes two buffers or two lists with the same entry type, and returns a concatenated buffer or list of the same entry type, with max_len = max_len_a + max_len_b.

Example

(concat "hello " "world") ;; Returns 0x68656c6c6f20776f726c64
                                            ;; hex form of "hello world"

contract-call?

Syntax (contract-call? .contract-name function-name arg0 arg1 ...)

INPUT: ContractName, PublicFunctionName, Arg0, ...
OUTPUT: (response A B)

The contract-call? function executes the given public function of the given contract. You may not use this function to call a public function defined in the current contract. If the public function returns err, any database changes resulting from calling contract-call? are aborted. If the function returns ok, database changes occurred.

Example

;; instantiate the sample-contracts/tokens.clar contract first!
(as-contract (contract-call? .tokens mint! u19)) ;; Returns (ok u19)

contract-of

Syntax (contract-of .contract-name)

INPUT: Trait
OUTPUT: principal

The contract-of function returns the principal of the contract implementing the trait.

Example

(use-trait token-a-trait 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF.token-a.token-trait)
(define-public (forward-get-balance (user principal) (contract <token-a-trait>))
  (begin
    (ok (contract-of contract)))) ;; returns the principal of the contract implementing <token-a-trait>

default-to

Syntax (default-to default-value option-value)

INPUT: A, (optional A)
OUTPUT: A

The default-to function attempts to ‘unpack’ the second argument: if the argument is a (some ...) option, it returns the inner value of the option. If the second argument is a (none) value, default-to it returns the value of default-value.

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(default-to 0 (get id (map-get? names-map (tuple (name "blockstack"))))) ;; Returns 1337
(default-to 0 (get id (map-get? names-map (tuple (name "non-existant"))))) ;; Returns 0

define-constant

Syntax (define-constant name expression)

INPUT: MethodSignature, MethodBody
OUTPUT: Not Applicable

define-constant is used to define a private constant value in a smart contract. The expression passed into the definition is evaluated at contract launch, in the order that it is supplied in the contract. This can lead to undefined function or undefined variable errors in the event that a function or variable used in the expression has not been defined before the constant.

Like other kinds of definition statements, define-constant may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Example

(define-constant four (+ 2 2))
(+ 4 four) ;; returns 8

define-data-var

Syntax (define-data-var var-name type value)

INPUT: VarName, TypeDefinition, Value
OUTPUT: Not Applicable

define-data-var is used to define a new persisted variable for use in a smart contract. Such variable are only modifiable by the current smart contract.

Persisted variable are defined with a type and a value.

Like other kinds of definition statements, define-data-var may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Example

(define-data-var size int 0)
(define-private (set-size (value int))
  (var-set size value))
(set-size 1)
(set-size 2)

define-fungible-token

Syntax (define-fungible-token token-name <total-supply>)

INPUT: TokenName, </code>
OUTPUT: Not Applicable

define-fungible-token is used to define a new fungible token class for use in the current contract.

The second argument, if supplied, defines the total supply of the fungible token. This ensures that all calls to the ft-mint? function will never be able to create more than total-supply tokens. If any such call were to increase the total supply of tokens passed that amount, that invocation of ft-mint? will result in a runtime error and abort.

Like other kinds of definition statements, define-fungible-token may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Tokens defined using define-fungible-token may be used in ft-transfer?, ft-mint?, and ft-get-balance functions

Example

(define-fungible-token stacks)
(define-fungible-token limited-supply-stacks u100)

define-map

Syntax (define-map map-name ((key-name-0 key-type-0) ...) ((val-name-0 val-type-0) ...))

INPUT: MapName, KeyTupleDefinition, MapTupleDefinition
OUTPUT: Not Applicable

define-map is used to define a new datamap for use in a smart contract. Such maps are only modifiable by the current smart contract.

Maps are defined with a key tuple type and value tuple type. These are defined using a list of name and type pairs, e.g., a key type might be ((id int)), which is a tuple with a single “id” field of type int.

Like other kinds of definition statements, define-map may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Example

(define-map squares ((x int)) ((square int)))
(define-private (add-entry (x int))
  (map-insert squares ((x 2)) ((square (* x x)))))
(add-entry 1)
(add-entry 2)
(add-entry 3)
(add-entry 4)
(add-entry 5)

define-non-fungible-token

Syntax (define-non-fungible-token asset-name asset-identifier-type)

INPUT: AssetName, TypeSignature
OUTPUT: Not Applicable

define-non-fungible-token is used to define a new non-fungible token class for use in the current contract. Individual assets are identified by their asset identifier, which must be of the type asset-identifier-type. Asset identifiers are unique identifiers.

Like other kinds of definition statements, define-non-fungible-token may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Assets defined using define-non-fungible-token may be used in nft-transfer?, nft-mint?, and nft-get-owner? functions

Example

(define-non-fungible-token names (buff 50))

define-private

Syntax (define-private (function-name (arg-name-0 arg-type-0) (arg-name-1 arg-type-1) ...) function-body)

INPUT: MethodSignature, MethodBody
OUTPUT: Not Applicable

define-private is used to define private functions for a smart contract. Private functions may not be called from other smart contracts, nor may they be invoked directly by users. Instead, these functions may only be invoked by other functions defined in the same smart contract.

Like other kinds of definition statements, define-private may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Private functions may return any type.

Example

(define-private (max-of (i1 int) (i2 int))
  (if (> i1 i2)
      i1
      i2))
(max-of 4 6) ;; returns 6

define-public

Syntax (define-public (function-name (arg-name-0 arg-type-0) (arg-name-1 arg-type-1) ...) function-body)

INPUT: MethodSignature, MethodBody
OUTPUT: Not Applicable

define-public is used to define a public function and transaction for a smart contract. Public functions are callable from other smart contracts and may be invoked directly by users by submitting a transaction to the Stacks blockchain.

Like other kinds of definition statements, define-public may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Public functions must return a ResponseType (using either ok or err). Any datamap modifications performed by a public function is aborted if the function returns an err type. Public functions may be invoked by other contracts via contract-call?.

Example

(define-public (hello-world (input int))
  (begin (print (+ 2 input))
         (ok input)))

define-read-only

Syntax (define-read-only (function-name (arg-name-0 arg-type-0) (arg-name-1 arg-type-1) ...) function-body)

INPUT: MethodSignature, MethodBody
OUTPUT: Not Applicable

define-read-only is used to define a public read-only function for a smart contract. Such functions are callable from other smart contracts.

Like other kinds of definition statements, define-read-only may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Read-only functions may return any type. However, read-only functions may not perform any datamap modifications, or call any functions which perform such modifications. This is enforced both during type checks and during the execution of the function. Public read-only functions may be invoked by other contracts via contract-call?.

Example

(define-read-only (just-return-one-hundred)
  (* 10 10))

define-trait

Syntax (define-trait trait-name ((func1-name (arg1-type arg2-type ...) (return-type))))

INPUT: VarName, [MethodSignature]
OUTPUT: Not Applicable

define-trait is used to define a new trait definition for use in a smart contract. Other contracts can implement a given trait and then have their contract identifier being passed as function arguments in order to be called dynamically with contract-call?.

Traits are defined with a name, and a list functions defined with a name, a list of argument types, and return type.

Like other kinds of definition statements, define-trait may only be used at the top level of a smart contract definition (i.e., you cannot put a define statement in the middle of a function body).

Example

(define-trait token-trait
    ((transfer? (principal principal uint) (response uint uint))
     (get-balance (principal) (response uint uint))))

err

Syntax (err value)

INPUT: A
OUTPUT: (response A B)

The err function constructs a response type from the input value. Use err for creating return values in public functions. An err value indicates that any database changes during the processing of the function should be rolled back.

Example

(err true) ;; Returns (err true)

filter

Syntax (filter func list)

INPUT: Function(A) -> bool, (list A)
OUTPUT: (list A)

The filter function applies the input function func to each element of the input list, and returns the same list with any elements removed for which the func returned false.

Example

(filter not (list true false true false)) ;; Returns (false false)

fold

Syntax (fold func list initial-value)

INPUT: Function(A, B) -> B, (list A), B
OUTPUT: B

The fold special form applies the input function func to each element of the input list and the output of the previous application of the fold function. When invoked on the first list element, it uses the initial-value as the second input. fold returns the last value returned by the successive applications. Note that the first argument is not evaluated thus has to be a literal function name.

Example

(fold * (list 2 2 2) 1) ;; Returns 8
(fold * (list 2 2 2) 0) ;; Returns 0
;; calculates (- 11 (- 7 (- 3 2)))
(fold - (list 3 7 11) 2) ;; Returns 5 
(fold concat "cdef" "ab")   ;; Returns 0x666564636162
                                ;; hex form of "fedcab"  
(fold concat (list "cd" "ef") "ab")   ;; Returns 0x656663646162
                                            ;; hex form of "efcdab"

ft-get-balance

Syntax (ft-get-balance token-name principal)

INPUT: TokenName, principal
OUTPUT: uint

ft-get-balance returns token-name balance of the principal principal. The token type must have been defined using define-fungible-token.

Example

(define-fungible-token stackaroo)
(ft-mint? stackaroo u100 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR)
(ft-get-balance stackaroo 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR) ;; returns u100

ft-mint?

Syntax (ft-mint? token-name amount recipient)

INPUT: TokenName, uint, principal
OUTPUT: (response bool uint)

ft-mint? is used to increase the token balance for the recipient principal for a token type defined using define-fungible-token. The increased token balance is not transfered from another principal, but rather minted.

If a non-positive amount is provided to mint, this function returns (err 1). Otherwise, on successfuly mint, it returns (ok true).

Example

(define-fungible-token stackaroo)
(ft-mint? stackaroo u100 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (ok true)

ft-transfer?

Syntax (ft-transfer? token-name amount sender recipient)

INPUT: TokenName, uint, principal, principal
OUTPUT: (response bool uint)

ft-transfer? is used to increase the token balance for the recipient principal for a token type defined using define-fungible-token by debiting the sender principal.

This function returns (ok true) if the transfer is successful. In the event of an unsuccessful transfer it returns one of the following error codes:

(err u1)sender does not have enough balance to transfer (err u2)sender and recipient are the same principal (err u3) – amount to send is non-positive

Example

(define-fungible-token stackaroo)
(ft-mint? stackaroo u100 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR)
(ft-transfer? stackaroo u50 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (ok true)
(ft-transfer? stackaroo u60 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (err u1)

get-block-info?

Syntax (get-block-info? prop-name block-height-expr)

INPUT: BlockInfoPropertyName, BlockHeightInt
OUTPUT: (optional buff) | (optional uint)

The get-block-info? function fetches data for a block of the given block height. The value and type returned are determined by the specified BlockInfoPropertyName. If the provided BlockHeightInt does not correspond to an existing block prior to the current block, the function returns none. The currently available property names are time, header-hash, burnchain-header-hash, id-header-hash, miner-address, and vrf-seed.

The time property returns an integer value of the block header time field. This is a Unix epoch timestamp in seconds which roughly corresponds to when the block was mined. Warning: this does not increase monotonically with each block and block times are accurate only to within two hours. See BIP113 for more information.

The header-hash, burnchain-header-hash, id-header-hash, and vrf-seed properties return a 32-byte buffer.

The miner-address property returns a principal corresponding to the miner of the given block.

The id-header-hash is the block identifier value that must be used as input to the at-block function.

Example

(get-block-info? time u0) ;; Returns (some u1557860301)
(get-block-info? header-hash u0) ;; Returns (some 0x374708fff7719dd5979ec875d56cd2286f6d3cf7ec317a3b25632aab28ec37bb)
(get-block-info? vrf-seed u0) ;; Returns (some 0xf490de2920c8a35fabeb13208852aa28c76f9be9b03a4dd2b3c075f7a26923b4)

get

Syntax (get key-name tuple)

INPUT: KeyName, (tuple) | (optional (tuple))
OUTPUT: A

The get function fetches the value associated with a given key from the supplied typed tuple. If an Optional value is supplied as the inputted tuple, get returns an Optional type of the specified key in the tuple. If the supplied option is a (none) option, get returns (none).

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-insert names-map { name: "blockstack" } { id: 1337 }) ;; Returns true
(get id (tuple (name "blockstack") (id 1337))) ;; Returns 1337
(get id (map-get? names-map (tuple (name "blockstack")))) ;; Returns (some 1337)
(get id (map-get? names-map (tuple (name "non-existent")))) ;; Returns none

hash160

Syntax (hash160 value)

INPUT: buff|uint|int
OUTPUT: (buff 20)

The hash160 function computes RIPEMD160(SHA256(x)) of the inputted value. If an integer (128 bit) is supplied the hash is computed over the little-endian representation of the integer.

Example

(hash160 0) ;; Returns 0xe4352f72356db555721651aa612e00379167b30f

if

Syntax (if bool1 expr1 expr2)

INPUT: bool, A, A
OUTPUT: A

The if function admits a boolean argument and two expressions which must return the same type. In the case that the boolean input is true, the if function evaluates and returns expr1. If the boolean input is false, the if function evaluates and returns expr2.

Example

(if true 1 2) ;; Returns 1
(if (> 1 2) 1 2) ;; Returns 2

impl-trait

Syntax (impl-trait trait-identifier)

INPUT: TraitIdentifier
OUTPUT: Not Applicable

impl-trait can be use for asserting that a contract is fully implementing a given trait. Additional checks are being performed when the contract is being published, rejecting the deployment if the contract is violating the trait specification.

Trait identifiers can either be using the sugared syntax (.token-a.token-trait), or be fully qualified (‘SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF.token-a.token-trait).

Like other kinds of definition statements, impl-trait may only be used at the top level of a smart contract definition (i.e., you cannot put such a statement in the middle of a function body).

Example

(impl-trait 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF.token-a.token-trait)

is-eq

Syntax (is-eq v1 v2...)

INPUT: A, A, ...
OUTPUT: bool

Compares the inputted values, returning true if they are all equal. Note that unlike the (and ...) function, (is-eq ...) will not short-circuit. All values supplied to is-eq must be the same type.

Example

(is-eq 1 1) ;; Returns true
(is-eq true false) ;; Returns false
(is-eq "abc" 234 234) ;; Throws type error

is-err

Syntax (is-err value)

INPUT: (response A B)
OUTPUT: bool

is-err tests a supplied response value, returning true if the response was an err, and false if it was an ok.

Example

(is-err (ok 1)) ;; Returns false
(is-err (err 1)) ;; Returns true

is-none

Syntax (is-none value)

INPUT: (optional A)
OUTPUT: bool

is-none tests a supplied option value, returning true if the option value is (none), and false if it is a (some ...).

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(is-none (get id (map-get? names-map { name: "blockstack" }))) ;; Returns false
(is-none (get id (map-get? names-map { name: "non-existant" }))) ;; Returns true

is-ok

Syntax (is-ok value)

INPUT: (response A B)
OUTPUT: bool

is-ok tests a supplied response value, returning true if the response was ok, and false if it was an err.

Example

(is-ok (ok 1)) ;; Returns true
(is-ok (err 1)) ;; Returns false

is-some

Syntax (is-some value)

INPUT: (optional A)
OUTPUT: bool

is-some tests a supplied option value, returning true if the option value is (some ...), and false if it is a none.

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(is-some (get id (map-get? names-map { name: "blockstack" }))) ;; Returns true
(is-some (get id (map-get? names-map { name: "non-existant" }))) ;; Returns false

keccak256

Syntax (keccak256 value)

INPUT: buff|uint|int
OUTPUT: (buff 32)

The keccak256 function computes KECCAK256(value) of the inputted value. Note that this differs from the NIST SHA-3 (that is, FIPS 202) standard. If an integer (128 bit) is supplied the hash is computed over the little-endian representation of the integer.

Example

(keccak256 0) ;; Returns 0xf490de2920c8a35fabeb13208852aa28c76f9be9b03a4dd2b3c075f7a26923b4

len

Syntax (len buffer)

INPUT: buff|list
OUTPUT: uint

The len function returns the length of a given buffer or list.

Example

(len "blockstack") ;; Returns u10
(len (list 1 2 3 4 5)) ;; Returns u5

let

Syntax (let ((name1 expr1) (name2 expr2) ...) expr-body1 expr-body2 ... expr-body-last)

INPUT: ((name2 AnyType) (name2 AnyType) ...), AnyType, ... A
OUTPUT: A

The let function accepts a list of variable name and expression pairs, evaluating each expression and binding it to the corresponding variable name. The context created by this set of bindings is used for evaluating its body expressions. The let expression returns the value of the last such body expression.

Example

(let ((a 2) (b (+ 5 6 7))) (print a) (print b) (+ a b)) ;; Returns 20

list

Syntax (list expr1 expr2 expr3 ...)

INPUT: A, ...
OUTPUT: (list A)

The list function constructs a list composed of the inputted values. Each supplied value must be of the same type.

Example

(list (+ 1 2) 4 5) ;; Returns (3 4 5)

map-delete

Syntax (map-delete map-name key-tuple)

INPUT: MapName, tuple
OUTPUT: bool

The map-delete function removes the value associated with the input key for the given map. If an item exists and is removed, the function returns true. If a value did not exist for this key in the data map, the function returns false.

Example

(define-map names-map ((name (buff 10))) ((id int)))
(map-insert names-map { name: "blockstack" } { id: 1337 }) ;; Returns true
(map-delete names-map { name: "blockstack" }) ;; Returns true
(map-delete names-map { name: "blockstack" }) ;; Returns false
(map-delete names-map ((name "blockstack"))) ;; Same command, using a shorthand for constructing the tuple

map-get?

Syntax (map-get? map-name key-tuple)

INPUT: MapName, tuple
OUTPUT: (optional (tuple))

The map-get? function looks up and returns an entry from a contract’s data map. The value is looked up using key-tuple. If there is no value associated with that key in the data map, the function returns a none option. Otherwise, it returns (some value).

Example

(define-map names-map ((name (buff 10))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(map-get? names-map (tuple (name "blockstack"))) ;; Returns (some (tuple (id 1337)))
(map-get? names-map ((name "blockstack"))) ;; Same command, using a shorthand for constructing the tuple

map-insert

Syntax (map-insert map-name key-tuple value-tuple)

INPUT: MapName, tuple_A, tuple_B
OUTPUT: bool

The map-insert function sets the value associated with the input key to the inputted value if and only if there is not already a value associated with the key in the map. If an insert occurs, the function returns true. If a value already existed for this key in the data map, the function returns false.

Note: the value-tuple requires 1 additional byte for storage in the materialized blockchain state, and therefore the maximum size of a value that may be inserted into a map is MAX_CLARITY_VALUE - 1.

Example

(define-map names-map ((name (buff 10))) ((id int)))
(map-insert names-map { name: "blockstack" } { id: 1337 }) ;; Returns true
(map-insert names-map { name: "blockstack" } { id: 1337 }) ;; Returns false
(map-insert names-map ((name "blockstack")) ((id 1337))) ;; Same command, using a shorthand for constructing the tuple

map-set

Syntax (map-set map-name key-tuple value-tuple)

INPUT: MapName, tuple_A, tuple_B
OUTPUT: bool

The map-set function sets the value associated with the input key to the inputted value. This function performs a blind update; whether or not a value is already associated with the key, the function overwrites that existing association.

Note: the value-tuple requires 1 additional byte for storage in the materialized blockchain state, and therefore the maximum size of a value that may be inserted into a map is MAX_CLARITY_VALUE - 1.

Example

(define-map names-map ((name (buff 10))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 }) ;; Returns true
(map-set names-map ((name "blockstack")) ((id 1337))) ;; Same command, using a shorthand for constructing the tuple

map

Syntax (map func list)

INPUT: Function(A) -> B, (list A)
OUTPUT: (list B)

The map function applies the input function func to each element of the input list, and outputs a list containing the outputs from those function applications.

Example

(map not (list true false true false)) ;; Returns (false true false true)

match

Syntax (match opt-input some-binding-name some-branch none-branch) | (match-resp input ok-binding-name ok-branch err-binding-name err-branch)

INPUT: (optional A) name expression expression | (response A B) name expression name expression
OUTPUT: C

The match function is used to test and destructure optional and response types.

If the input is an optional, it tests whether the provided input is a some or none option, and evaluates some-branch or none-branch in each respective case.

Within the some-branch, the contained value of the input argument is bound to the provided some-binding-name name.

Only one of the branches will be evaluated (similar to if statements).

If the input is a response, it tests whether the provided input is an ok or err response type, and evaluates ok-branch or err-branch in each respective case.

Within the ok-branch, the contained ok value of the input argument is bound to the provided ok-binding-name name.

Within the err-branch, the contained err value of the input argument is bound to the provided err-binding-name name.

Only one of the branches will be evaluated (similar to if statements).

Note: Type checking requires that the type of both the ok and err parts of the response object be determinable. For situations in which one of the parts of a response is untyped, you should use unwrap-panic or unwrap-err-panic instead of match.

Example

(define-private (add-10 (x (optional int)))
  (match x
  value (+ 10 value)
  10))
(add-10 (some 5)) ;; returns 15
(add-10 none) ;; returns 10

(define-private (add-or-pass-err (x (response int (buff 10))) (to-add int))
  (match x
   value (+ to-add value)
   err-value (err err-value)))
(add-or-pass-err (ok 5) 20) ;; returns 25
(add-or-pass-err (err "ERROR") 20) ;; returns (err "ERROR")

mod

Syntax (mod i1 i2)

INPUT: int, int | uint, uint
OUTPUT: int | uint

Returns the integer remainder from integer dividing i1 by i2. In the event of a division by zero, throws a runtime error.

Example

(mod 2 3) ;; Returns 2
(mod 5 2) ;; Returns 1
(mod 7 1) ;; Returns 0

nft-get-owner?

Syntax (nft-get-owner? asset-class asset-identifier)

INPUT: AssetName, A
OUTPUT: (optional principal)

nft-get-owner? returns the owner of an asset, identified by asset-identifier, or none if the asset does not exist. The asset type must have been defined using define-non-fungible-token, and the supplied asset-identifier must be of the same type specified in that definition.

Example

(define-non-fungible-token stackaroo (buff 40))
(nft-mint? stackaroo "Roo" 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF)
(nft-get-owner? stackaroo "Roo") ;; Returns (some SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF)
(nft-get-owner? stackaroo "Too") ;; Returns none

nft-mint?

Syntax (nft-mint? asset-class asset-identifier recipient)

INPUT: AssetName, A, principal
OUTPUT: (response bool uint)

nft-mint? is used to instantiate an asset and set that asset’s owner to the recipient principal. The asset must have been defined using define-non-fungible-token, and the supplied asset-identifier must be of the same type specified in that definition.

If an asset identified by asset-identifier already exists, this function will return an error with the following error code:

(err u1)

Otherwise, on successfuly mint, it returns (ok true).

Example

(define-non-fungible-token stackaroo (buff 40))
(nft-mint? stackaroo "Roo" 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (ok true)

nft-transfer?

Syntax (nft-transfer? asset-class asset-identifier sender recipient)

INPUT: AssetName, A, principal, principal
OUTPUT: (response bool uint)

nft-transfer? is used to change the owner of an asset identified by asset-identifier from sender to recipient. The asset-class must have been defined by define-non-fungible-token and asset-identifier must be of the type specified in that definition.

This function returns (ok true) if the transfer is successful. In the event of an unsuccessful transfer it returns one of the following error codes:

(err u1)sender does not own the asset (err u2)sender and recipient are the same principal (err u3) – asset identified by asset-identifier does not exist

Example

(define-non-fungible-token stackaroo (buff 40))
(nft-mint? stackaroo "Roo" 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR)
(nft-transfer? stackaroo "Roo" 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (ok true)
(nft-transfer? stackaroo "Roo" 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (err u1)
(nft-transfer? stackaroo "Stacka" 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF) ;; returns (err u3)

not

Syntax (not b1)

INPUT: bool
OUTPUT: bool

Returns the inverse of the boolean input.

Example

(not true) ;; Returns false
(not (is-eq 1 2)) ;; Returns true

ok

Syntax (ok value)

INPUT: A
OUTPUT: (response A B)

The ok function constructs a response type from the input value. Use ok for creating return values in public functions. An ok value indicates that any database changes during the processing of the function should materialize.

Example

(ok 1) ;; Returns (ok 1)

or

Syntax (or b1 b2 ...)

INPUT: bool, ...
OUTPUT: bool

Returns true if any boolean inputs are true. Importantly, the supplied arguments are evaluated in-order and lazily. Lazy evaluation means that if one of the arguments returns false, the function short-circuits, and no subsequent arguments are evaluated.

Example

(or true false) ;; Returns true
(or (is-eq (+ 1 2) 1) (is-eq 4 4)) ;; Returns true
(or (is-eq (+ 1 2) 1) (is-eq 3 4)) ;; Returns false
(or (is-eq (+ 1 2) 3) (is-eq 4 4)) ;; Returns true

pow

Syntax (pow i1 i2)

INPUT: int, int | uint, uint
OUTPUT: int | uint

Returns the result of raising i1 to the power of i2. In the event of an overflow, throws a runtime error.

Example

(pow 2 3) ;; Returns 8
(pow 2 2) ;; Returns 4
(pow 7 1) ;; Returns 7

print

Syntax (print expr)

INPUT: A
OUTPUT: A

The print function evaluates and returns its input expression. On Blockstack Core nodes configured for development (as opposed to production mining nodes), this function prints the resulting value to STDOUT (standard output).

Example

(print (+ 1 2 3)) ;; Returns 6

sha256

Syntax (sha256 value)

INPUT: buff|uint|int
OUTPUT: (buff 32)

The sha256 function computes SHA256(x) of the inputted value. If an integer (128 bit) is supplied the hash is computed over the little-endian representation of the integer.

Example

(sha256 0) ;; Returns 0x374708fff7719dd5979ec875d56cd2286f6d3cf7ec317a3b25632aab28ec37bb

sha512/256

Syntax (sha512/256 value)

INPUT: buff|uint|int
OUTPUT: (buff 32)

The sha512/256 function computes SHA512/256(x) (the SHA512 algorithm with the 512/256 initialization vector, truncated to 256 bits) of the inputted value. If an integer (128 bit) is supplied the hash is computed over the little-endian representation of the integer.

Example

(sha512/256 1) ;; Returns 0x515a7e92e7c60522db968d81ff70b80818fc17aeabbec36baf0dda2812e94a86

sha512

Syntax (sha512 value)

INPUT: buff|uint|int
OUTPUT: (buff 64)

The sha512 function computes SHA512(x) of the inputted value. If an integer (128 bit) is supplied the hash is computed over the little-endian representation of the integer.

Example

(sha512 1) ;; Returns 0x6fcee9a7b7a7b821d241c03c82377928bc6882e7a08c78a4221199bfa220cdc55212273018ee613317c8293bb8d1ce08d1e017508e94e06ab85a734c99c7cc34

some

Syntax (some value)

INPUT: A
OUTPUT: (optional A)

The some function constructs a optional type from the input value.

Example

(some 1) ;; Returns (some 1)
(is-none (some 2)) ;; Returns false

stx-burn?

Syntax (stx-burn? amount sender)

INPUT: uint, principal
OUTPUT: (response bool uint)

stx-burn? debits the sender principal’s STX holdings by amount, destroying the STX. The sender principal must be equal to the current context’s tx-sender.

This function returns (ok true) if the transfer is successful. In the event of an unsuccessful transfer it returns one of the following error codes:

(err u1)sender does not have enough balance to transfer (err u3) – amount to send is non-positive (err u4) – the sender principal is not the current tx-sender

Example

(as-contract
  (stx-burn? u60 tx-sender)) ;; returns (ok true)
(as-contract
  (stx-burn? u50 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR)) ;; returns (err u4)

stx-get-balance

Syntax (stx-get-balance owner)

INPUT: principal
OUTPUT: uint

stx-get-balance is used to query the STX balance of the owner principal.

This function returns the STX balance of the owner principal. In the event that the owner principal isn’t materialized, it returns 0.

Example

(stx-get-balance 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR) ;; returns u0
(stx-get-balance (as-contract tx-sender)) ;; returns u10000

stx-transfer?

Syntax (stx-transfer? amount sender recipient)

INPUT: uint, principal, principal
OUTPUT: (response bool uint)

stx-transfer? is used to increase the STX balance for the recipient principal by debiting the sender principal. The sender principal must be equal to the current context’s tx-sender.

This function returns (ok true) if the transfer is successful. In the event of an unsuccessful transfer it returns one of the following error codes:

(err u1)sender does not have enough balance to transfer (err u2)sender and recipient are the same principal (err u3) – amount to send is non-positive (err u4) – the sender principal is not the current tx-sender

Example

(as-contract
  (stx-transfer? u60 tx-sender 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR)) ;; returns (ok true)
(as-contract
  (stx-transfer? u50 'SZ2J6ZY48GV1EZ5V2V5RB9MP66SW86PYKKQ9H6DPR tx-sender)) ;; returns (err u4)

to-int

Syntax (to-int u)

INPUT: uint
OUTPUT: int

Tries to convert the uint argument to an int. Will cause a runtime error and abort if the supplied argument is >= pow(2, 127)

Example

(to-int u238) ;; Returns 238

to-uint

Syntax (to-uint i)

INPUT: int
OUTPUT: uint

Tries to convert the int argument to a uint. Will cause a runtime error and abort if the supplied argument is negative.

Example

(to-uint 238) ;; Returns u238

try!

Syntax (try! option-input)

INPUT: (optional A) | (response A B)
OUTPUT: A

The try! function attempts to ‘unpack’ the first argument: if the argument is an option type, and the argument is a (some ...) option, try! returns the inner value of the option. If the argument is a response type, and the argument is an (ok ...) response, try! returns the inner value of the ok. If the supplied argument is either an (err ...) or a none value, try! returns either none or the (err ...) value from the current function and exits the current control-flow.

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(try! (map-get? names-map { name: "blockstack" })) ;; Returns (tuple (id 1337))
(define-private (checked-even (x int))
  (if (is-eq (mod x 2) 0)
      (ok x)
      (err false)))
(define-private (double-if-even (x int))
  (ok (* 2 (try! (checked-even x)))))
(double-if-even 10) ;; Returns (ok 20)
(double-if-even 3) ;; Returns (err false)

tuple

Syntax (tuple ((key0 expr0) (key1 expr1) ...))

INPUT: (key-name A), (key-name-2 B), ...
OUTPUT: (tuple (key-name A) (key-name-2 B) ...)

The tuple function constructs a typed tuple from the supplied key and expression pairs. A get function can use typed tuples as input to select specific values from a given tuple. Key names may not appear multiple times in the same tuple definition. Supplied expressions are evaluated and associated with the expressions’ paired key name.

Example

(tuple (name "blockstack") (id 1337))

unwrap!

Syntax (unwrap! option-input thrown-value)

INPUT: (optional A) | (response A B), C
OUTPUT: A

The unwrap! function attempts to ‘unpack’ the first argument: if the argument is an option type, and the argument is a (some ...) option, unwrap! returns the inner value of the option. If the argument is a response type, and the argument is an (ok ...) response, unwrap! returns the inner value of the ok. If the supplied argument is either an (err ...) or a (none) value, unwrap! returns thrown-value from the current function and exits the current control-flow.

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(define-private (get-name-or-err (name (buff 12)))
  (let ((raw-name (unwrap! (map-get? names-map { name: name }) (err 1))))
       (ok raw-name)))

(get-name-or-err "blockstack") ;; Returns (ok (tuple (id 1337)))
(get-name-or-err "non-existant") ;; Returns (err 1)

unwrap-err!

Syntax (unwrap-err! response-input thrown-value)

INPUT: (response A B), C
OUTPUT: B

The unwrap-err! function attempts to ‘unpack’ the first argument: if the argument is an (err ...) response, unwrap-err! returns the inner value of the err. If the supplied argument is an (ok ...) value, unwrap-err! returns thrown-value from the current function and exits the current control-flow.

Example

(unwrap-err! (err 1) false) ;; Returns 1

unwrap-err-panic

Syntax (unwrap-err-panic response-input)

INPUT: (response A B)
OUTPUT: B

The unwrap-err function attempts to ‘unpack’ the first argument: if the argument is an (err ...) response, unwrap returns the inner value of the err. If the supplied argument is an (ok ...) value, unwrap-err throws a runtime error, aborting any further processing of the current transaction.

Example

(unwrap-err-panic (err 1)) ;; Returns 1
(unwrap-err-panic (ok 1)) ;; Throws a runtime exception

unwrap-panic

Syntax (unwrap-panic option-input)

INPUT: (optional A) | (response A B)
OUTPUT: A

The unwrap function attempts to ‘unpack’ its argument: if the argument is an option type, and the argument is a (some ...) option, this function returns the inner value of the option. If the argument is a response type, and the argument is an (ok ...) response, it returns the inner value of the ok. If the supplied argument is either an (err ...) or a (none) value, unwrap throws a runtime error, aborting any further processing of the current transaction.

Example

(define-map names-map ((name (buff 12))) ((id int)))
(map-set names-map { name: "blockstack" } { id: 1337 })
(unwrap-panic (map-get? names-map { name: "blockstack" })) ;; Returns (tuple (id 1337))
(unwrap-panic (map-get? names-map { name: "non-existant" })) ;; Throws a runtime exception

use-trait

Syntax (use-trait trait-alias trait-identifier)

INPUT: VarName, TraitIdentifier
OUTPUT: Not Applicable

use-trait is used to bring a trait, defined in another contract, to the current contract. Subsequent references to an imported trait are signaled with the syntax <trait-alias>.

Traits import are defined with a name, used as an alias, and a trait identifier. Trait identifiers can either be using the sugared syntax (.token-a.token-trait), or be fully qualified (‘SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF.token-a.token-trait).

Like other kinds of definition statements, use-trait may only be used at the top level of a smart contract definition (i.e., you cannot put such a statement in the middle of a function body).

Example

(use-trait token-a-trait 'SPAXYA5XS51713FDTQ8H94EJ4V579CXMTRNBZKSF.token-a.token-trait)
(define-public (forward-get-balance (user principal) (contract <token-a-trait>))
  (begin
    (ok 1)))

var-get

Syntax (var-get var-name)

INPUT: VarName
OUTPUT: A

The var-get function looks up and returns an entry from a contract’s data map. The value is looked up using var-name.

Example

(define-data-var cursor int 6)
(var-get cursor) ;; Returns 6

var-set

Syntax (var-set var-name expr1)

INPUT: VarName, AnyType
OUTPUT: bool

The var-set function sets the value associated with the input variable to the inputted value.

Example

(define-data-var cursor int 6)
(var-get cursor) ;; Returns 6
(var-set cursor (+ (var-get cursor) 1)) ;; Returns true
(var-get cursor) ;; Returns 7

xor

Syntax (xor i1 i2)

INPUT: int, int | uint, uint
OUTPUT: int | uint

Returns the result of bitwise exclusive or’ing i1 with i2.

Example

(xor 1 2) ;; Returns 3
(xor 120 280) ;; Returns 352